MODULE: TypedText 0.7.0

[Crimson Wizard]

DOWNLOAD TypedText 0.7.0 (beta version) MODULE PACK
Archive contains modules: TypedText, TypedTextHelper and TypedTextDrawing.
DOWNLOAD Demo Game

Latest source code may be found here
Git cloning address: https://ivan-mogilko@bitbucket.org/ivan-mogilko/ags-script-modules.git
Demo Game git cloning address: https://ivan-mogilko@bitbucket.org/ivan-mogilko/ags-script-demos.git

Module supports AGS 3.2.1 and higher


Introduction

TypedText module provides means for displaying continiously typed text, also known as typewriter style display. Letter appears by letter with certain delay in between.

A while ago I was scripting a typing text animation for a game project; later I found out that there is already Phemar's Typewriter module, but it did not allow the kind of behavior that the project required, so I continued with my own script.
Now I found some free time to rewrite that script in a cleaner way and make an actual script module of it. But I also copied few things from Phemar's module, to make TypedText suitable for the needs of people who used Phemar's module before.

The general peculiarity of this module, and also what makes it different from existing one, is that it is based on a Type (struct), and objects of that type, instead of a Function. This leads to following effects:
1. You can have multiple typed text animations simultaneously.
2. Since objects keep their states in them, you may have both blocking and non-blocking typed texts.
3. Having an object with exposed interface (public functions and properties) make it possible to alter its behavior on fly, as well as override it, and use it to create your own custom typewriters.


Using an object may be more complicated than using a single function, and require time to study it, so I added TypedTextHelper module with number of "helper" functions to make it easier to start using TypedText in your project. Also those functions may be just what you need if standart behavior is enough. This is why I will explain their use before going into detail about TypedText itself.

But first I need to quickly clarify on some concepts.


TypedText concepts

TypedText simulates continious text typing, letter by letter. When doing so it passes several states:

Inactive - this is when it has no text set whatsoever.
Typing text - this is when it is in process of typing text.
Waiting for reader - this is when all text was fully typed and displayed on screen, but settings demand TypedText to wait a little longer to give human an opportunity to finish reading the text.
Idling - this is when typing and waiting is complete, and TypedText is not going to do anything else.

NOTE: Helper functions, such as those that display TypedText on Overlays, rely on "waiting for reader" state to know when typed text should be removed from screen.

TypedText has a concept of the flashing caret. Depending on setup, it may flash last typed letter, or draw certain symbol behind typed text (like '_', for example).
The caret, if enabled, commences to flash whenever delay between two typed letters is greater than caret's waiting timer. This timer resets when next letter is typed. This also means that when all  the text was already typed, caret will then flash endlessly (so long as TypedText is on screen).

Keeping the above in mind, TypedText relies on following parameters:

Typing delay - how many game ticks to wait after each typed letter.
Typing delay style - this concept is copied from Phemar's module, and defines delay behavior for spaces and caret-returns in the text (are they same, slower than usual or faster than usual),
Caret depiction - is the caret is depicted anyway, and how: this may be flashing last letter, or specific string drawn in the end, or even a sprite - for the advanced TypedText implementations.
Caret flash times - how long caret stays on screen and stays hidden when it flashes.
Text reading time - how much time, in game ticks, is spent on reading 1 letter: this parameter is used to calculate average reading time of a text.

Finally, extended variants of TypedText also support sound that is played whenever next letter was typed.


Using TypedTextHelper

TypedTextHelper module requires TypedText module to present above it in the modules list.

It provides a number of functions to run typed text blocking or non-blocking, in a number of ways: on a Button, on a Label, or on an Overlay.

Because TypedText has a significant number of parameters, many of which are supposed to stay same for the most of the time in game, I thought it would be very inconvenient to put all of those parameters into functions. Instead, TypedTextHelper has a special preset system.
This works pretty simple actually: you setup least changing properties as a preset under certain ID, and then use that preset ID when starting typed text on Label, or Overlay; this makes all of that preset's parameters to be used for that instance of text typing.

Following are preset functions you may use:

Code: ags

/// Set general parameters for the specified preset
TypewriterPreset.SetGeneral(int preset, int delay_min, int delay_max, TypedDelayStyle style, int read_time = 12);
/// Set caret parameters for the specified preset
TypewriterPreset.SetCaret(int preset, int flash_on_time, int flash_off_time, TypedCaretStyle style, String caret_str, int caret_sprite = 0);
/// Set sound parameters for the specified preset
TypewriterPreset.SetSounds(int preset, AudioClip *type_sound, AudioClip *caret_sound, AudioClip *end_sound);
TypewriterPreset.SetSoundArray(int preset, AudioClip *type_sounds[], int type_sound_count,
                                 AudioClip *caret_sound, AudioClip *end_sound);

Maximal number of presets is determined with TYPEDTEXTHELPER_MAXPRESETS constant in the module header. It is 8 by default, but you may increase it if you need more.
Maximal number of sounds that you may assign for preset and each typewriter is determined with TYPEDTEXTRENDER_MAXSOUNDS contant.

Best place to set preset's parameters is "game_start" function, but you may change them anytime by using same preset ID.

After you set up at least one preset, you may begin using helper functions. All of them are made as extender functions, which means you first type object (Button, Label, Character) pointer name, then call the function from it, like:

Code: ags

// NOTE: preset is optional, and will be 0 if you don't type anything
/// Print TypedText as a text on button
SomeButton.Typewriter(String text, BlockingStyle bs, int preset = 0);
/// Print TypedText as a text on label
SomeLabel.Typewriter(String text, BlockingStyle bs, int preset = 0);

The only difference is Overlay static extender (static extenders is a new thing since AGS 3.4.0), where you do not use overlay's pointer, but just "Overlay" word:

Code: ags

// NOTE: preset is optional, and will be 0 if you don't type anything
/// Print TypedText as a text on created overlay
Overlay.Typewriter(int x, int y, int color, FontType font, String text, BlockingStyle bs, int preset = 0);

If you are working in pre-3.4.0, you will have to use non-extender function for overlays, called TypewriteOnOverlay, but it works essentially same, and has same parameters (except it is not called from Overlay).


If you run these functions with eBlock, they will display typed text inside of them, and return when typing (and waiting) state has finished.
If you run them with eNoBlock, they will return back immediately, but typed text will work on a background, updated from repeatedly_execute inside the module.

You may run only one blocking typed text at the same time.
Maximal simultaneous non-blocking typed texts is determined by TYPEDTEXTHELPER_MAXTYPEWRITERS constant in the module header. It is 8 by default, but you may increase it if you need more.


Each of those helper functions return unique ID of typewriter. If you want to control that typewriter, such as detect when it stops typing, or be able to cancel it, store this ID in a variable for later. You may then use this ID with TypewriterRunners static functions and properties:

Code: ags

/// Get number of currently running typewriters
int TypewriterRunners.ActiveCount;
/// Get number of maximal supported typewriters that can run simultaneously
int TypewriterRunners.MaxCount;
/// Get whether given typewriter ID is currently running (use unique ID as an array index)
bool TypewriterRunners.IsActive[];
/// Get whether given typewriter ID is blocking (use unique ID as an array index)
bool TypewriterRunners.IsBlocking[];
/// Stop typewriter under given ID
void Cancel(int id);

The principal example:

Code: ags

int tw_id = SomeButton.Typewriter(text, eNoBlock);

<... later ...>

if (TypewriterRunners.IsActive[tw_id])
  TypewriterRunners.Cancel(tw_id); // interrupt typewriter if it was still running

Using TypedText directly

If above helper functions do not do what you like, you may create and use objects of TypedText struct, or any derived structs, directly.

TypedText struct's purpose is to calculate timing and  basic state of the text. It does not draw anything on screen on its own, but calculates and tells how the text should look like at any given moment, letting you to use that information as you see fit. In other words, it tells what is happening, but does not tell you how it should look (and sound) like.


Setting up TypedText is fairly straighforward, here are its configuration properties:

Code: ags

/// Base delay (in ticks) between every typing event
import attribute int              TypeDelay;
/// Bounds for random base delay
import attribute int              TypeDelayMin;
import attribute int              TypeDelayMax;
import attribute TypedDelayStyle  TypeDelayStyle;
/// Time (in ticks) the caret stays shown
import attribute int              CaretFlashOnTime;
/// Time (in ticks) the caret stays hidden
import attribute int              CaretFlashOffTime;
/// Time (in ticks) given to read one text character
import attribute int              TextReadTime;


/// Whitespace/caret-return delay style defines relation of special case
/// delays to the base type delay.
/// Idea is conforming to the Phemar's Typewriter module.
enum TypedDelayStyle
{
  /// wait for the same amount of time as after regular letters
  eTypedDelay_Uniform = 0,
  /// wait twice as long after whitespaces
  eTypedDelay_LongSpace,
  /// wait twice as less after whitespaces
  eTypedDelay_ShortSpace,
  /// randomly choose a style every time
  eTypedDelay_Mixed
};

And its control methods are:

Code: ags

  
/// Gets/sets paused state
import attribute bool             Paused;

/// Clears all text and resets all timers
import void                       Clear();
/// Sets new string, resets all timers and commences typing
import void                       Start(String text);
/// Skips all the remaining typing
import void                       Skip();

/// Update typed text state, advancing it by single tick
import void                       Tick();

Since you are using TypedText yourself, you need to be continiously checking its state in repeating function:

Code: ags

/// Full string that has to be typed
readonly import attribute String  FullString;
/// Part of string that is supposed to be shown at current time
readonly import attribute String  CurrentString;
/// Part of string that was 'typed' during latest update
readonly import attribute String  LastTyped;

/// Tells whether TypedText has active content to process or display
readonly import attribute bool    IsActive;
/// Tells whether TypedText is in process of typing text
/// (return FALSE if either no text is set, or text is already fully typed)
readonly import attribute bool    IsTextBeingTyped;
/// Tells whether TypedText is waiting for the text to be read by player
/// (return FALSE when reading timer has ran out, regardless of other states)
readonly import attribute bool    IsWaitingForReader;
/// Tells whether TypedText is currently idling, either not having a content,
/// or after finishing all the required actions (typing & waiting for reader)
readonly import attribute bool    IsIdle;
/// Tells whether caret should be currently displayed
readonly import attribute bool    IsCaretShown;

/// Gets if the new character was just typed
readonly import attribute bool    EvtCharTyped;
/// Gets if the text has just ended being typed
readonly import attribute bool    EvtFinishedTyping;

One of the simpliest examples for using TypedText is this:

Code: ags

// in GlobalScript.asc
TypedText my_tt;

function game_start()
{
    // Config typed text to your liking
    my_tt.TypeDelay = 4;
    my_tt.CaretFlashOnTime = 4;
    my_tt.CaretFlashOffTime = 4;
}

// Calling TypeSay will start typed text
function TypeSay(string s)
{
    my_tt.Start(s);
}

function repeatedly_execute()
{
    if (my_tt.IsIdle)
    {
        my_tt.Clear(); // clear the text, stop timers ticking, etc
    }
    else if (my_tt.IsActive)
    {
        my_tt.Tick(); // update TT
        String text_to_show = my_tt.CurrentString;
        if (my_tt.IsCaretShown)
            text_to_show = text_to_show.Append("_"); // append caret symbol to the end of the text
        player.Saybackground(text_to_show); // print TT's current text as a player's background speech
    }
}

Using TypewriterRender and its subtypes

There is a number of extended types provided by the module, which add bit more functionality. First is struct TypewriterRender, which extends TypedText, and other structs extend TypewriterRender further.

As was mentioned above, TypedText does not draw anything on its own, only calculates the text's state. TypewriterRender does not do much too, but it adds few more properties and serves rather like a base class for actual visualizing:

Code: ags

/// Caret display style
import attribute TypedCaretStyle CaretStyle;
/// A string (or single character) that represents typewriter caret
import attribute String          CaretString;

/// The only sound to play when a character is typed
import attribute AudioClip *     TypeSound;
/// Array of sounds to choose at random when a character is typed
readonly import attribute AudioClip *TypeSounds[];
/// Number of typing sounds registered
readonly import attribute int    TypeSoundCount;
/// Sound to play when the line break is met
import attribute AudioClip *     CaretSound;
/// Sound to play when the typewriter finished typing text
import attribute AudioClip *     EndSound;

/// Sets the array of sounds to play at random when character is typed
import void                      SetRandomTypeSounds(AudioClip *sounds[], int count);


/// Style of the caret displayed during typing
enum TypedCaretStyle
{
  /// No caret display
  eTypedCaret_None = 0, 
  /// Flash last character
  eTypedCaret_LastChar, 
  /// Draw separate caret at the next assumed character location
  eTypedCaret_Explicit
};

The actual workers are inheriting types: TypewriterButton, TypewriterLabel, TypewriterOverlay. They have respective properties to set up an object they will print text on (or from which perspective), as well as their own overwritten Clear, Start and Tick methods.

Using them you will avoid necessity to draw text yourself:

Code: ags

// in GlobalScript.asc
TypewriterLabel my_tt_label;

function game_start()
{
    my_tt_label.TypeOnLabel = lblTypewriter; // put your actual label's name here
    my_tt_label.TypeDelay = 4;
    my_tt_label.CaretFlashOnTime = 4;
    my_tt_label.CaretFlashOffTime = 4;
    my_tt_label.CaretStyle = eTypedCaret_LastChar; // make last char flash
    my_tt_label.TypeSound = aTypewriterTyping; // set sound to play
}

// Calling TypeOnLabel will start typed text
function TypeOnLabel(string s)
{
    my_tt_label.Start(s);
}

function repeatedly_execute()
{
    if (my_tt_label.IsIdle)
        my_tt_label.Clear(); // remove text when done typing & waiting for the reader
    else if (my_tt_label.IsActive)
        my_tt_label.Tick(); // update text
    // notice that you do not need to point where to print the text anymore,
    // TypewriterLabel already knows that and does printing for you
}

Using TypedTextDrawing

TypedTextDrawing is an advanced struct, extending TypewriterRender, that lets you draw typed text on DrawingSurface. This means you may have typewriter text on literally anything that can give drawing surfaces or have assigned image: room and GUI backgrounds, objects, character frames even (crazy).
Besides, TypedTextDrawing is the only one of the provided types that can draw caret as a sprite.

TypedTextDrawing is located in its own separate module (of same name) and requires TypedText module to work (but not TypedTextHelper).

Setting TypedTextDrawing up is very similar to setting other TypedText subtypes, but you also need to set up its position on DrawingSurface, text color and font, and optionally background color.

What is more important to remember, you must explicitly call Draw function, because you need to pass DrawingSurface pointer to its drawing. It cannot store DrawingSurface once for use later, because that goes against rules of using drawing surfaces (they have to be released right after every use).

Here is some example, that draws typed text on a room's backround

Code: ags

// in GlobalScript.asc
TypedTextDrawing tt_draw;
DynamicSprite *roomBkg; // will keep saved room background

function game_start()
{
    tt_draw.TypeDelay = 4;
    tt_draw.CaretFlashOnTime = 4;
    tt_draw.CaretFlashOffTime = 4;
    tt_draw.CaretStyle = eTypedCaret_Explicit; // draw caret
    tt_draw.CaretSprite = 1010; // put your sprite number here
    tt_draw.TypeSound = aTypewriterTyping; // set sound to play
    
    tt_draw.X = 40;
    tt_draw.Y = 40;
    tt_draw.Width = Room.Width - 80;
    tt_draw.Height = Room.Height - 80;
    tt_draw.Font = eFontText;
    tt_draw.TextAlign = eAlignCentre;
}

function RestoreRoomBkg()
{
    // Restore original room background
    DrawingSurface *ds = Room.GetDrawingSurfaceForBackground();
    ds.DrawImage(0, 0, roomBkg.Graphic);
    ds.Release();
}

// Calling TypeOnDS will start typed text
function TypeOnDS(string s)
{
    if (roomBkg == null)
    {
        roomBkg = DynamicSprite.CreateFromBackground();
    }
    else
    {
        RestoreRoomBkg();
    }
    tt_draw.Start(s);
}

function repeatedly_execute()
{
    if (tt_draw.IsIdle)
    {
        tt_draw.Clear();
        RestoreRoomBkg();
    }
    else if (tt_draw.IsActive)
    {
        tt_draw.Tick(); // update TT
        DrawingSurface *ds = Room.GetDrawingSurfaceForBackground();
        tt_draw.Draw(ds);
        ds.Release();
    }
}

Other script modules by me:
DragDrop module
KeyListener

[Cassiebsg]

Uhm... you give me weird ideas with the module.
Thanks a bunch for the hard work! Sure will try it, if I need the functionality of a typewriter.

[Crimson Wizard]

Next beta version: 0.6.5
Download: https://bitbucket.org/ivan-mogilko/ags-script-modules/downloads/TypedText_0.6.5.zip
A little demo-game (compiled files only for now) just to quickly demonstrate how this thing works: https://bitbucket.org/ivan-mogilko/ags-script-modules/downloads/TypedTextDemo%200.6.5.zip


What has changed since 0.6.0:

1. Most importantly, I realized that there is no way to know when typing animation finished if you run non-blocking helper. So I added whole new static struct to the TypedTextHelper module:

Code: ags

#define NO_TYPEWRITER 0

struct TypewriterRunners
{
  /// Get number of currently running typewriters
  readonly import static attribute int  ActiveCount;
  /// Get number of maximal supported typewriters that can run simultaneously
  readonly import static attribute int  MaxCount;
  /// Get whether given typewriter ID is currently running
  readonly import static attribute bool IsActive[];
  /// Get whether given typewriter ID is blocking
  readonly import static attribute bool IsBlocking[];
  
  /// Stop typewriter under given ID
  import static void Cancel(int id);
};

To put it simply, each Typewriter helper function (like Button.Typewriter, Overlay.Typewrite, etc) now returns unique typewriter ID, that then can be used to retrieve information, or interrupt typing, like this:

Code: ags

int tw_id = SomeButton.Typewriter(text, eNoBlock);

<...later...>

if (TypewriterRunners.IsActive[tw_id])
  TypewriterRunners.Cancel(tw_id);

2. Made modules compatible with AGS 3.2.1, in case people still using that version. (I know some still use 2.72, but I do not feel like going there)
Before AGS 3.4.0 you need to use "TypewriteOnOverlay" instead of "Overlay.Typewriter".

3. Renamed helper extenders from TypewriterPrint to just Typewriter, so they are now Button.Typewriter, and so on.

[Crimson Wizard]

Next beta version: 0.7.0
Download: https://bitbucket.org/ivan-mogilko/ags-script-modules/downloads/TypedText_0.7.0.zip
Finally a Demo Game with proper source: https://bitbucket.org/ivan-mogilko/ags-script-demos/downloads/TypedTextDemo_0.7.0.zip


What has changed since 0.6.5:

1. First of all, I completely removed TypewriterSpeech class and related helper function. It did not do anything very useful anyway at this point.
When it comes to speech there is a lot of things that need to be taken care about (animation, voice-over, etc), and I feel that currently TypedText module is at such stage where the priority is to make its basic intended behavior to work well.
It is still very much possible to create speech using TypewriterOverlay class; in fact the example of such speech (combined with Phylactere's module bubble) is featured in the Demo Game.

2. I fixed (hopefully) an issue that caused some words to begin appear at one line and then suddenly jump to another. This was related to difference in how TypedText and built-in AGS classes I print text to manage their contents. Fixing this problem allowed me to correctly detect when the new line starts, which helped in implementing CaretSound (see below).

3. More sound options are available now for TypewriterRender and all its descendants (TypewriterButton, *Label and *Overlay).
- Instead of having only one sound for typing, you can now supply your typewriter with an array of audio clips to choose at random when every next letter gets typed. Since I am supporting pre-3.4.0 versions of AGS, which did not allow dynamic arrays in structs, the TYPEDTEXTRENDER_MAXSOUNDS macro is defining how many typing sounds max each typewriter may have. You may increase or decrease this value if you wish. An array of clips is added using SetRandomTypeSounds function.
- CaretSound property lets you define a sound to play when typing starts at the next line (or rather when previous line ended?).
- EndSound property lets you define a sound to play when text finished typing.

4. Fixes in TypedTextDrawing:
- Some properties were missing their implementation.
- There were few mistakes related to wrapped lines alignment.


Make sure to check the DemoGame out, and click on everything you see there (not much, but fun, I hope) .
Personally, I think the module works pretty solid now. There are couple of more things I'd like to add in the future, but that may not be too soon.

[Cassiebsg]

Okay, this seems way more complex to use than I initially thought it would...
I'm trying to do something very simple, which is basically type the text non-blocking while some other blocking speech is running... but I'm basically drawing a blank... In other words, nothing is being typed, while the rest of my code runs perfectly, once it ends and shows the menu GUI, I get a square white box that will type my text, letter by letter, every time I click my mouse... twice.
Not exactly what I had in mind.

Thought it would be easier to work with, like add the settings to the start of the script, and then used TypedText(text) to show the lines...

[Crimson Wizard]

I'm trying to do something very simple, which is basically type the text non-blocking while some other blocking speech is running...

Hmm... doing something non-blocking while blocking speech is running, is probably not possible, because these typewriters are updated in repeatedly_execute.

Try opening TypedTextHelper.asc and changing "repeatedly_execute" function to "repeatedly_execute_always", and see if that works for you.

I guess I need to add an option for either running these typewriters in "always" or normal repeating function.

[Cassiebsg]

Managed to get it to display on the room now, but the text doesn't get typed unless I press the mouse button or the enter key. Plus, there's still a white box displaying, instead of the background.

Maybe you can figure out what I'm doing wrong here? I removed the code for the BG video and speech for now.
EDIT: I put the code in Room 1, since it's the only room that I'll be using for all the text. Not sure if that makes a difference or not.

Code: ags

// text script for room
TypedTextDrawing tt_draw;
DynamicSprite *roomBkg; // will keep saved room background
 
function game_start()
{
    tt_draw.TypeDelay = 4;
    tt_draw.CaretFlashOnTime = 4;
    tt_draw.CaretFlashOffTime = 4;
    tt_draw.CaretStyle = eTypedCaret_Explicit; // draw caret
    tt_draw.CaretSprite = 1010; // put your sprite number here
    //tt_draw.TypeSound = aTypewriterTyping; // set sound to play
    
    tt_draw.X = 40;
    tt_draw.Y = 40;
    tt_draw.Width = Room.Width - 80;
    tt_draw.Height = Room.Height - 80;
    tt_draw.Font = eFontGalactican;
    tt_draw.TextAlign = eAlignCentre;
}
 
function RestoreRoomBkg()
{
    // Restore original room background
    DrawingSurface *ds = Room.GetDrawingSurfaceForBackground();
    ds.DrawImage(0, 0, roomBkg.Graphic);
    ds.Release();
}
 
// Calling TypeOnDS will start typed text
function TypeOnDS(string st)
{
    if (roomBkg == null)
    {
        roomBkg = DynamicSprite.CreateFromBackground();
    }
    else
    {
        RestoreRoomBkg();
    }
    tt_draw.Start(st);
}
 
D3D_Video* video;
TypedText my_text;
     
function repeatedly_execute_always() 
{   
    if (tt_draw.IsActive)
    {
        tt_draw.Tick(); // update TT
        if (tt_draw.IsIdle)
        {
            tt_draw.Clear();
            RestoreRoomBkg();
        }
        else
        {
            DrawingSurface *ds = Room.GetDrawingSurfaceForBackground();
            tt_draw.Draw(ds);
            ds.Release();
        }
    }
	if (my_text.IsActive)
	{
		my_text.Tick(); // update TypedText
		if (my_text.IsIdle)
		{
			my_text.Clear(); // clear the text
		}
		else
		{
			String text_to_show=my_text.CurrentString;
			if (my_text.IsCaretShown)
			{
				text_to_show=text_to_show.Append("_"); // append carret symbol to the end of the text
			}
			DisplayAt(140, 113, 500, text_to_show); // print typedText's current text 
		}
	}
}
 
function room_Load() 
{
	// Config typed text
	my_text.TypeDelay=4;
	my_text.CaretFlashOnTime=4;
	my_text.CaretFlashOffTime=4;
	// End config of type text
	
	/*	SetViewport(0, 0);
		cShuttle.Transparency=100;
		cShuttle.Baseline=288;
		cShuttle.ChangeRoom(1, 199, 139);
	*/
}

function TypeSay(String st)
{
	my_text.Start(st);
}



void Cutscene_Intro()
{	

	 TypeSay("An AGS game by Sandra T. Almeida");
}


function room_AfterFadeIn()
{
	if (Game.DoOnceOnly("Play Intro")) Cutscene_Intro();
}

PS - I changed the sting from s to st, as the s was giving me a parse error.

[Crimson Wizard]

You are calling DisplayAt from repeatedly_execute_always, and it blocks your game completely until you press key or click mouse.

What are your intentions for typed text? TypedText class is not really meant for simple cases, it is for more complex cases when you need a custom behavior.

[Cassiebsg]

oh, right, forgot that display blocks. I put displayAt so I got possition the text, but now that I'm looking at the code, I think I spot where I should change that.

Let me so try with sayBG, brb.

EDIT: Okay, that worked. Well, almost, since for some reason didn't used my font nor it printed the last letter.
Also, why is the text scrolling to the left? I wanted it to start at one position and write to the right.

EDIT: Seems to be completely ignoring the settings at game start (I realize it game start wasn't doing anything in the room, and moved it to room_load) but seems to still be ignoring it.

[Crimson Wizard]

EDIT: Okay, that worked. Well, almost, since for some reason didn't used my font nor it printed the last letter.
Also, why is the text scrolling to the left? I wanted it to start at one position and write to the right.

You have "tt_draw.TextAlign = eAlignCentre;" probably you need eAlignLeft.
Not sure about the font...


EDIT:
Oh and about the last letter, I think there is a mistake in my example, the update code should be something like:

Code: ags

    if (tt_draw.IsIdle)
    {
        tt_draw.Clear();
        RestoreRoomBkg();
    }
    else if (tt_draw.IsActive)
    {
        tt_draw.Tick(); // update TT
        DrawingSurface *ds = Room.GetDrawingSurfaceForBackground();
        tt_draw.Draw(ds);
        ds.Release();
    }

The "IsIdle" part is only necessary if you want it to remove text automatically as soon as finished waiting for reader. You can change reading speed with tt_draw.TextReadTime. Or remove text by your own method.

[Cassiebsg]

Seems to be completely ignoring the settings at game start (I realized that game start wasn't doing anything in the room, and moved it to room_load) but seems to still be ignoring it.

Okay, I'll change that code, but I solved that problem by just adding [ at the end of the text.

[Crimson Wizard]

Seems to be completely ignoring the settings at game start (I realized that game start wasn't doing anything in the room, and moved it to room_load) but seems to still be ignoring it.

Well... there might be something very simple, like room_load not entered on events panel, or something like that.

[Cassiebsg]

No, it is linked, that's why I moved the code there.
I have other code in there that is being initialized in the room.

[Crimson Wizard]

Can you show the final code, please?

[Cassiebsg]

Code: ags

// text script for room
TypedTextDrawing tt_draw;
DynamicSprite *roomBkg; // will keep saved room background
 

function RestoreRoomBkg()
{
    // Restore original room background
    DrawingSurface *ds = Room.GetDrawingSurfaceForBackground();
    ds.DrawImage(0, 0, roomBkg.Graphic);
    ds.Release();
}
 
// Calling TypeOnDS will start typed text
function TypeOnDS(string st)
{
    if (roomBkg == null)
    {
        roomBkg = DynamicSprite.CreateFromBackground();
    }
    else
    {
        RestoreRoomBkg();
    }
    tt_draw.Start(st);
}
 
function repeatedly_execute()
{
}
 
D3D_Video* video;
TypedText my_text;
     
function repeatedly_execute_always() 
{   
    if (tt_draw.IsActive)
    {
        tt_draw.Tick(); // update TT
        if (tt_draw.IsIdle)
        {
            tt_draw.Clear();
            RestoreRoomBkg();
        }
        else
        {
            DrawingSurface *ds = Room.GetDrawingSurfaceForBackground();
            tt_draw.Draw(ds);
            ds.Release();
        }
    }
    if (my_text.IsActive)
    {
        my_text.Tick(); // update TypedText
        if (my_text.IsIdle)
        {
            my_text.Clear(); // clear the text
        }
        else
        {
            String text_to_show=my_text.CurrentString;
            if (my_text.IsCaretShown)
            {
                text_to_show=text_to_show.Append(""); // append carret symbol to the end of the text
            }
            cNarrat.SayBackground(text_to_show); // print typedText's current text 
        }
    }
}
 
function room_Load() 
{
    tt_draw.TypeDelay = 4;
    tt_draw.CaretFlashOnTime = 4;
    tt_draw.CaretFlashOffTime = 4;
    tt_draw.CaretStyle = eTypedCaret_Explicit; // draw caret
    tt_draw.CaretSprite = 1010; // put your sprite number here
    //tt_draw.TypeSound = aTypewriterTyping; // set sound to play
	
    tt_draw.X = 500;
    tt_draw.Y = Room.Height / 2;
    tt_draw.Width = 500 ;
    tt_draw.Height = Room.Height / 2 ;
    tt_draw.Font = eFontGalactican;
    tt_draw.TextAlign = eAlignLeft;
    // Config typed text
    my_text.TypeDelay=4;
    my_text.CaretFlashOnTime=4;
    my_text.CaretFlashOffTime=4;
    // End config of type text
	
    //	SetViewport(0, 0);
    cShuttle.Transparency=100;
    cShuttle.Baseline=288;
    cShuttle.ChangeRoom(1, 199, 139);
}

function TypeSay(String st)
{
    my_text.Start(st);
}



void Cutscene_Intro()
{	
    //bool Esc_CutScene=false;
    //D3D Plugin - playing background video with Theora-------------
    //Required for autoplay
    D3D.SetLoopsPerSecond( GetGameSpeed() );
    
    // Open video file
    video = D3D.OpenVideo( "Intro_Opening_v1.ogv" );
    
    if ( video )
    {
        // Use room coordinates
        video.relativeTo = eD3D_RelativeToRoom;
        
        // Anchor point to top left corner
        video.SetAnchor( -0.5, -0.5 );
        
        // Play!
        video.Autoplay();
    }
    else
    {
        player.SayBackground( "Couldn't open video." );
        
    }
    //END OF D3D plugin video---------------------------------------
    play_Music(Intro);
    StartCutscene(eSkipESCOnly);
    //	oGal.Visible=true;
    // oGal.SetView(60);
    TypeSay("An AGS game by Sandra T. Almeida[");
	 
    cNarrat.SayAt(6, 261, 500, "&1 There are those who believe");   
    cNarrat.SayAt(6, 261, 500, "&2 that life here began out there,");
    TypeSay("a fan game based on Battlestar Galactica[");
    cNarrat.SayAt(6, 261, 500, "&3 far across the universe,");
    cNarrat.SayAt(6, 261, 500, "&4 with tribes of humans");
    cNarrat.SayAt(6, 261, 500, "&5 who may have been the forefathers of the Egyptians");
    cNarrat.SayAt(6, 261, 500, "&6 or the Toltecs or the Mayans.");
    //  oGal.Animate(0, 1, eOnce, eNoBlock, eForwards);
    cNarrat.SayAt(6, 261, 500, "&7 Some believe that there may yet be brothers of man");
    cNarrat.SayAt(6, 261, 500, "&8 who even now fight to survive");
    cNarrat.SayAt(6, 261, 500, "&9 somewhere beyond the heavens.");
    play_Music(Main);
    while (video.NextFrame()) 
    {
        if (IsKeyPressed(eKeyEscape)) break;
        else Wait(1);
    }
    EndCutscene();
    video=null; 
    CloseM.Visible=false;
    gMenu.Visible=true;
}

function room_AfterFadeIn()
{
    if (Game.DoOnceOnly("Play Intro")) Cutscene_Intro();
}

void Cutscene_Start()
{	
    //D3D Plugin - playing background video with Theora-------------
    // Required for autoplay
    D3D.SetLoopsPerSecond( GetGameSpeed() );
    
    // Open video file
    video = D3D.OpenVideo( "test.ogg" );
    
    if ( video )
    {
        // Use room coordinates
        video.relativeTo = eD3D_RelativeToRoom;
        
        // Anchor point to top left corner
        video.SetAnchor( -0.5, -0.5 );
        
        // Play!
        video.Autoplay();
    }
    else
    {
        Display( "Couldn't open video." );
        //return;
    }
	//END OF D3D plugin video---------------------------------------
	
    SetGameSpeed(25); // you don't need to use the same fps as the video like this, but it's easiest this way*/
	
	
    cAthena.ChangeRoom(1, 1024, 0);
    cNarrat.ChangeRoom(1, -5, 0);
    cNarrat.SpeechView=97;
    cShuttle.SetAsPlayer();
    //cAthena.SpeechView=18;
    //oGal.StopAnimating();
    Start_Cutscene=false;
    StartCutscene(eSkipESCOnly);
    play_Music(Intro);
    oGal.Graphic=1213;
    oGal.Visible=true;
    oBay.Visible=true;
    cShuttle.Transparency=0;
    cShuttle.Walk(948, 201, eNoBlock, eAnywhere);
    //oShuttle.Visible=true;
    //oShuttle.Move(492, 201, -2, eNoBlock, eAnywhere);
    // oShuttle.SetView(VSHUTTLE);
    //oShuttle.Animate(0, 2000, eOnce, eNoBlock, eForwards);
    //cNarrat.SayAt(6, 261, 500, "&11 What's Starbuck's status?");
    cNarrat.Say("&11 What's Starbuck's status?");
    Wait(10);
    ReleaseViewport();
    //cAthena.SayAt(6, 261, 500, "&45 He's due on the Rising Star at any moment.");
    cAthena.Say("&45 He's due on the Rising Star at any moment.");
    Wait(5);
    cNarrat.Say("&12 I hope we don't have to move him to red before he eats.");
    //oShuttle.Move(939, 142, -2, eNoBlock, eAnywhere);
    cShuttle.Walk(948, 137, eNoBlock, eAnywhere);
    cAthena.Say("&46 Starbuck did ask me to dinner tonight but...");
    cAthena.Say("&47 Well, I do have this duty.");
    cAthena.Say("&48 I guess he'll have to eat alone.");
    cShuttle.Walk(948, 135, eNoBlock, eAnywhere);
    cNarrat.Say("&13 Well, er... perhaps this once we can make an exception, hm?");
    Wait(5);
    cNarrat.Say("&14 You go ahead and join him.");
    cNarrat.Say("&15 I'll handle this with Colonel Tigh.");
    //	oShuttle.Visible=false;
    Wait(60);
    oGal.Visible=false;
    oBay.Visible=false;
    EndCutscene();
    play_Music(Stb);
    cStarb.SetAsPlayer();
    video=null; 
    SetGameSpeed(SldSpeed.Value);
    player.ChangeRoom(2, 309, 582);
}


function room_RepExec()
{
    if (Start_Cutscene) Cutscene_Start();
}

EDIT: Indent was out of wack...

EDIT2: Maybe it's the characterSay? And the speech font is being enforced over the settings?

[Crimson Wizard]

But, you are not even calling TypeOnDS anywhere in your script, which means that SayBackground is the only thing that shows up.

Something I have to clarify, do you realize that you have TWO completely separate typedtexts in your script? And you are starting only one of them, which is called my_text, but not the one called tt_draw?

[Cassiebsg]

No, I told you I had no idea what I was doing. Not that as easy to use this module.

So, how do I call the tt_draw, then? And how do I call TypeOnDS??

Or: What code should I be using?

[Crimson Wizard]

No, I told you I had no idea what I was doing. Not that as easy to use this module.

So, how do I call the tt_draw, then? And how do I call TypeOnDS??

Or: What code should I be using?

It looks like you copied two different code examples into one script.
If you wanted to draw typed text on room background you only need one with TypedTextDrawing.
In your current script simply replace calls to TypeSay with calls to TypeOnDS. This function already exists in your script.


I will see if I am able to rewrite description to make it easier to understand how to use this module.

[Cassiebsg]

Okay, replacing TypeSay with TypeOnDS rproduces: Erro (line 137): Type mismatch: cannot convert 'const string' to 'string'

I looked at the code, and if I replace function TypeOnDS(string st) with function TypeOnDS(String st)
then it runs, but I can't see the text being printed on screen.

[Crimson Wizard]

Sorry, but I think this module is not ready. I am cancelling it until I have time to work more on it.